DATASET CLOSE ALL.
OUTPUT CLOSE ALL.

SET SEED 12.
INPUT PROGRAM.
LOOP #Locations = 1 TO 25000.
  COMPUTE #RandEff = RV.NORMAL(0,1).
  LOOP #Time = 1 TO 2.
      COMPUTE Time = #Time.
      COMPUTE Loc = #Locations.
      COMPUTE #CovRE_BW = 0.2.
      COMPUTE BW = #CovRE_BW*#RandEff + RV.NORMAL(0,SQRT(1-#CovRE_BW)).
      COMPUTE RandEff = #RandEff.
      COMPUTE #BWEff_C = 0.1.
      COMPUTE #REff_C = 0.9.
      COMPUTE #Err_C = SQRT(1 - (#BWEff_C**2 + #REff_C**2 + 2*(#CovRE_BW**2))).
      COMPUTE Crime = 5 + #BWEff_C*BW + #REff_C*RandEff + RV.NORMAL(0,#Err_C).
      END CASE.
  END LOOP.
END LOOP.
END FILE.
END INPUT PROGRAM.

*Descriptives, all should have 1 variance, zero means except crime=5.
FREQ Crime BW RandEff /FORMAT = NOTABLE /STATISTICS = MEAN VAR.
CORRELATIONS  /VARIABLES=BW RandEff Crime.

*Correct Model.
REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BW RandEff.

*Ommitted variable model.
REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BW.

*Lags Model.
DO IF Loc = LAG(Loc).
  COMPUTE CrimeLag = LAG(Crime).
  COMPUTE BWLag = LAG(BW).
END IF.

REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BWLag CrimeLag.

REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BWLag.

REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BW CrimeLag.

*Incorporate other covariates.
VECTOR Oth(10).
DO REPEAT Oth = Oth1 TO Oth10.
  COMPUTE Oth = 0.5*RandEff + RV.NORMAL(0,SQRT(1-0.5)).
END REPEAT.

REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BW
  /METHOD=ENTER Oth1
  /METHOD=ENTER Oth2
  /METHOD=ENTER Oth3
  /METHOD=ENTER Oth4 TO Oth10.

REGRESSION
  /MISSING LISTWISE
  /DEPENDENT Crime
  /METHOD=ENTER BW CrimeLag Oth1 TO Oth10.